Finanza personale

Questa funzione serve per determinare quale sarà il pagamento periodico costante che dovrò effettuare per raggiungere un certo valore futuro. Se iniziamo a fare pratica con le altre funzioni finanziarie di Microsoft Excel, con questa funzione avremo uno strumento in più per poter valutare diverse opportunità di finanziamento o investimento.

La sintassi, ormai nota, segue le stesse regole e ordini delle precedenti funzioni:

=RATA(tasso; periodi; valore_attuale; valore_futuro; tipo)

Anche in questo caso è importante capire che la funzione RATA() darà un risultato con un segno in armonia con quelli impostati negli argomenti. Se cerchiamo la rata di un pagamento con un valore futuro positivo, RATA() darà un valore negativo; se cerchiamo la rata di un pagamento con valore attuale negativo, RATA() restituirà un valore con segno positivo.

Inoltre la rata/pagamento che otterremo, sarà un flusso finanziario sempre riferito al periodo. In questo modo se, ad esempio, il tasso di interesse è trimestrale, il valore che otterremo sarà trimestrale. Partiremo da qualche semplice esempio fino ad arrivare ai casi più intricati.

Esempio nr.1

Quale rata mensile dovremo pagare per un prestito di 200.000 Euro in 10 anni al tasso dello 0,5% mensile?

I periodi saranno 10 x 12 = 120, e il valore attuale 200.000 Euro. la formula sarà:

=RATA (tasso; periodi; valore_attuale; valore_futuro; tipo)

=RATA(0,5%; 120; 200000; 0; 0)

Il risultato della funzione sarà 2.220 Euro al mese (vedi figura 1).

Proviamo a fare un controllo incrociato per verificare che il nostro calcolo sia corretto. Potremmo, ora che le conosciamo, utilizzare le funzioni VA() o TASSO(). Proviamo con VA.

Sappiamo che il valore attuale nel nostro esempio è di 200.000 Euro, quindi impostando le altre variabili dovremo ottenere questo risultato. Dovremo scrivere:

=VA (tasso; periodi; rata; valore_futuro; tipo)

=VA(0,5%; 120; -2220; 0; 0)

Il risultato è esatto, infatti viene esattamente 200.000 Euro (vedi figura 2).

Proviamo ora con la funzione TASSO(), utilizzando sempre le stesse informazioni. Il nostro obiettivo è ottenere un tasso periodale del 0,5%.

La formula sarà:

=TASSO(periodi; rata; valore_attuale;valore_futuro; tipo; ipotesi)

=TASSO(120;-2220,41; 200000; 0; 0)

Il risultato è proprio 0,50% (figura 3), quindi siamo certi che il nostro conto è esatto.

Vediamo ora un altro esempio un pò più complesso.

Esempio nr.2

Ho a disposizione un capitale iniziale di 50.000 Euro e voglio portarlo a 1 Milione di Euro. Se rimango 10 anni in azienda mi è stato promesso un premio fedeltà di 50.000 Euro. Quanto devo risparmiare ogni mese per arrivare alla meta sapendo che posso contare su un interesse annuale nominale del 7%?

Se applichiamo le formule dei tassi equivalenti , un tasso annuo del 7% nominale sarà uguale al tasso mensile convertito per 12 periodi:
=(1+i) ^ (1/p)-1

=(1+0,07) ^ (1/12)-1 = 0,5654% (x 12 = 6,78% tasso annuo effettivo)

Quindi il tasso da prendere nel nostro caso è lo 0,5654% mensile.

Con questa premessa, il nostro calcolo deve considerare un valore futuro di 1 milione di Euro, 120 periodi, un valore attuale di 50.000 Euro e un valore futuro (da sottrarre) di 50.000 Euro: l’azienda infatti ci fornirà 50.000 Euro “futuri”, quindi noi dovremmo risparmiare “solo” 950.000 Euro: il valore futuro dei 50.000 Euro che già possediamo.

In formule:

=RATA (tasso; periodi; valore_attuale; valore_futuro; tipo)

=RATA (0,5654%; 120; -50000; 950000; 0)

Scopriamo cosi che con “soli” 4.978,92 Euro mensili, possiamo diventare milionari… (vedi figura 4).

Ma sarà vero? Verifichiamolo con le funzioni di cui siamo a conoscenza iniziando con VA().

La domanda da porci in questo caso è: quanto dovremmo avere in conto corrente per arrivare ad accumulare un Milione di Euro accantonando 4.978,92 Euro al mese e al tasso dello 0,5654% mensile? La risposta dovrà essere 50.000 Euro…

E’ presto detto: basta utilizzare lo schema dell’esempio nr.1 (lo trovate nella cartella .xls da scaricare) e sostituire i valori per VA() e TASSO()

Attraverso l’uso della funzione VA(), riusciamo ad ottenere infatti un capitale iniziale (valore attuale) di 50.000 Euro. La stessa verifica però potremmo farla utilizzando la funzione VAL.FUT().

Sapendo che il nostro Valore Futuro (montante) dovrà essere i Milione di Euro
– 50.000 Euro di premio, dovremmo verificare se la formula finanziaria ci riporta lo stesso risultato inserendo gli argomenti corretti.

Quindi:

=VALFUT(tasso; periodi; rata; valore_attuale; tipo)

=VALFUT(0,5654%; 120; – 4978,92; 50000; 0; 0)

Esperimento riuscito! La funzione riporta esattamente 950.000 Euro, cioè l’accumulo dei pagamenti più gli interessi più il capitale iniziale, meno i 50.000 Euro di premio.

Da questo link potete scaricare la cartella di lavoro di Excel contenente i dati relativi al primo ed al secondo esempio.

Il valore futuro di un qualsiasi investimento altro non è che il montante di un’operazione finanziaria. Ricordiamo qui sotto la formula del montante in regime di capitalizzazione composta.

C è il Capitale iniziale, i è il tasso periodale di interesse e t è il numero dei periodi di capitalizzazione.

Microsoft Excel ha bisogno di almeno 3 dei seguenti cinque argomenti per eseguire il calcolo: tasso, periodi, rata, valore attuale, tipo. Vediamo subito un esempio.

Esempio nr.1

Supponiamo che qualcuno ci proponga di investire 50 Euro al mese per 10 anni ad un tasso annuo convertibile mensilmente (cioè direttamente divisibile per i periodi di rateizzazione) del 12% annuale. Quanto potremo sperare di ritirare al termine del nostro investimento?

Il tasso è espresso su base annua, ma dobbiamo ricondurlo al valore mensile. Essendo convertibile il calcolo sarà: 12% annuo = (12/12)% mensile, cioè 1% al mese. I periodi sono 12 mesi per 10 anni, cioè 12 x 10 = 120. Non versiamo né riceviamo nulla alla partenza del periodo, quindi l’argomento valore attuale è zero. Il tipo di pagamento, inizialmente, lo ipotizziamo posticipato, quindi il valore dell’argomento “tipo” è zero. Detto ciò, la nostra formula sarà:

=VAL.FUT(tasso; periodi; rata; valore attuale; tipo)

=VALFUT(1%;120;-50;0;0)

Che da un valore di Euro 11.501,93 come si vede in figura 1.

Se nell’esempio precedente dovessimo invece considerare le rate come anticipate, quale sarebbe il montante finale? In questo caso occorre inserire il valore “1” nell’argomento “tipo”.

La formula sarà:

=VAL.FUT(tasso; periodi; rata; valore attuale; tipo)

=VALFUT(1%;120;-50;0;1)

Che da invece un valore di Euro 11.616,95 come si vede in figura 2.

In questo caso risulta evidente come il versamento anticipato (cioè all’inizio del primo mese in questo esempio) delle rate generi un montante più alto a fine periodo. Vediamo un esempio un p0’ più complesso.

Esempio nr.2

Decidiamo di aderire ad un piano di accumulo della nostra banca che prevede il versamento di 2000 Euro alla sottoscrizione, 200 Euro anticipati ogni 3 mesi con remunerazione sia del versamento iniziale, sia dei versamenti successivi ad un tasso di interesse del 3% netto trimestrale. Quale sarà il saldo del nostro conto corrente dopo 5 anni?

In questo caso il tasso è già espresso nella forma periodale, quindi non sono necessari ulteriori calcoli. I periodi richiedono un’attenzione maggiore: ci sono 4 trimestri in un anno (12/3) e dobbiamo considerare un arco temporale di 5 anni.

I periodi saranno pertanto 4 x 5 = 20. Sarà invece necessario prevedere nella nostra formula l’inserimento del valore attuale che, nel nostro esempio, è pari a 2000. Passando alla formula, essa sarà:

=VAL.FUT(tasso; periodi; rata; valore attuale; tipo)

=VALFUT(1%;120;-50;0;1)

La formula ci restituisce il valore di Euro 9.147,52 che rappresenta quindi il montante o valore futuro dell’intera operazione. In altre parole il saldo del nostro corrente tra 5 anni.

A questo punto potremmo essere già soddisfatti, ma noi pensiamo che le formule di Excel non vadano utilizzate senza averne capito esattamente il significato! Ecco che allora nella cartella di lavoro di Excel scaricabile in fondo a questo post, abbiamo inserito altri 2 fogli di lavoro, ‘Posticipato’ e ‘Anticipato’, contenenti lo sviluppo manuale del piano di accantonamento del nostro PAC.

In particolare nel primo foglio (Posticipato) riportiamo riga per riga i 21 accantonamenti (compreso quello iniziale di Euro 2000,00) in corrispondenza della colonna B (Pagamenti) mentre in colonna C riportiamo il montante di ogni singolo pagamento riferito alla data finale (periodo 20)

Se ora impostate il valore 0 (Zero) per l’argomento Tipo (cella B7 del foglio ‘Funzione Val.Fut()’) otterete l’esatta corrispondenza dei valori calcolati dalla formula e dalla sommatoria dei montanti in fondo al foglio ‘Posticipato’ (Euro 8.986,30).

Nel terzo foglio (Anticipato) la formula del montante relativa al primo termine (versamento iniziale) al periodo 0 è invariata, mentre per i termini successivi è stato aggiunto ‘1’ all’esponente della formula, ad esempio per il secondo termine la formula in C3 è +B3*(1+0,03)^(20-A3+1).

In questo modo si tiene conto del fatto che l’interesse si riferisce alla rata precedente e non a quella successiva!

Notate che ora sia il totale della sommatoria dei montanti di cella C24 sia il risultato iniziale della formula (con argomento Tipo=1 = rate anticipate) è il medesimo, e cioè Euro 9.147,52!

Da questo link potete scaricare la cartella di lavoro di Excel contenente i dati di questo secondo esempio.

A volte può essere interessante capire qual è il tasso di interesse di un certo investimento in modo da poterlo confrontare con un altro.

La funzione TASSO() è una funzione straordinariamente potente che può venirci in aiuto. Ovviamente la funzione da come risultato un tasso effettivo periodale, quindi, per ottenere l’equivalente tasso annuale effettivo, occorrerà elevare (1-i) alla potenza data dal numero di periodi cli capitalizzazione nell’anno e sottrarre 1.

In figura 1 vediamo gli argomenti della funzione Tasso. In grassetto gli argomenti obbligatori della funzione; l’ultimo argomento (ipotesi) è necessario usarlo solo in pochi casi.

La sintassi prevede gli stessi argomenti delle altre funzioni con l’aggiunta dell’argomento “ipotesi”. Questo argomento serve al programma quando il calcolo è molto complesso e si articola in un elevato numero di periodi; dal momento che Excel procede “by trial and error” il numero di iterazioni richieste può essere molto pesante.

In questi casi (la funzione restituisce un errore di tipo #Num!), occorre ipotizzare un tasso di interesse (periodale, ovviamente) di partenza.

In realtà, però, è piuttosto raro che sia richiesto l’utilizzo di questo argomento. La sintassi prevede questi argomenti:

=TASSO(periodi; rata; val. attuale; val. futuro; tipo; ipotesi)

Iniziamo subito con un esempio pratico per entrare nel vivo della funzione.

Vogliamo acquistare un Bot e ci dicono che depositando 4.800 Euro, dopo un anno otterremo 5.000 Euro. Qual’è è il tasso dell’operazione?

I periodi di capitalizzazione nell’esempio sono uguali a 1, cosi come 1 è l’anno in considerazione. Il problema può essere risolto in due modi a seconda di come interpretiamo i 4.800 Euro di versamento. Li consideriamo una rata anticipata? La formula in questo caso sarà:

=TASSO(periodi; rata; val. attuale; val. futuro; tipo; ipotesi)

=TASSO(1;-4800;0;5000;1)

Per semplificare il calcolo, il foglio di lavoro è organizzato in modo da inserire da un lato il numero di capitalizzazioni in un anno, dall’altro il numero di anni. Questo semplifica il lavoro e consente di automatizzare la conversione dei tassi da periodale ad annuale.

Il numero di capitalizzazioni per anno è determinato sostanzialmente dal numero di rate (equidistanti) in un anno; se paghiamo una rata trimestrale, pagheremo 4 rate, se paghiamo una rata settimanale pagheremo 52 rate e così via. Se, invece, considerassimo i 4800 Euro un valore attuale iniziale, allora potremmo scrivere la formula così:

=TASSO(periodi; rata; val. attuale; val. futuro; tipo; ipotesi)

=TASSO(1;0;-4800;5000;1)

Come è possibile notare, in questo caso, è la stessa cosa considerare un’unica rata anticipata o il valore attuale dell’investimento. il tasso sarà sempre 4,2%.

Vediamo un altro esempio. Un brillante consulente finanziario ci propone un investimento a suo dire eccezionale: rate anticipate mensili da 500 Euro l’una e, dopo 5 anni, ci viene restituito un capitale di 33.000 Euro. Qual è il tasso dell’operazione? La soluzione di questo problema ci darà il tasso mensile effettivo.

Per ottenere il corrispondente tasso effettivo annuo dovremo aggiungere 1, elevare alla dodicesima e sottrarre 1. I periodi di capitalizzazione saranno 12 e gli anni 5.

La formula sarà:

=TASSO(periodi; rata; val. attuale; val. futuro; tipo; ipotesi)

=TASSO(60;-500;0;33.000;1)

In figura 2 vediamo gli argomenti della funzione TASSO e lo sviluppo della soluzione per questo esempio.

Poi dovremo ottenere il tasso equivalente annuo, cioè:

(1+i)^p-1, quindi:

=(1 + B10)^B2-1 = (1 + 0,3%)^12-1 = 3,8%

Da questo link potete scaricare il foglio di lavoro di Excel con i dati dei 2 esempi.

Il comando Ricerca obiettivo ci viene in aiuto nel momento in cui vogliamo ottenere un risultato specifico da una formula andando a modificare uno dei valori determinanti il risultato.

Invece di perdere tempo procedendo per tentativi, potete ottenere subito risultati precisi grazie a questo semplice strumento.

Immaginate di richiedere un prestito alla vostra banca alle segenti condizioni:

Prestito iniziale: € 35.000,00

Tasso annuale nominale: 6%

Periodicità rate: mensile

Numero delle rate: 60

Importa della rata: € 676,65

Immaginate ora di voler vedere come varia l’importo della rata se la durata del prestito passa da cinque a quattro anni, mantenendo inalterato il tasso di interesse.

Dal menù Strumenti di Excel, selezionate il comando Ricerca obiettivo. Vedi figura 1.

Fate clic nel primo campo (Imposta le cella) e selezionate la cella (D2) contenente il numero delle rate. Nel secondo campo (al valore) inserite il numero di rate (48) corrispondente a un prestito di 4 anni.

Fate dunque clic nell’ultimo campo (Cambiando la cella) e selezionate il valore che dovrà variare per ottenere le nuove condizioni (B2, l’importo della rata).

Fate clic su OK ed Excel calcolerà l’ammontare della rata corrispondente alla nuova durata del prestito (€ 821,98) . A questo punto potrete decidere se accettare il nuovo risultato, facendo clic su OK, o rifiutarlo scegliendo Annulla. Vedi figura 2.

Tenere presente che la cella variabile (l’importo della rata nel nostro esempio) deve sempre contenere un numero, non importa se negativo o positivo, ma non può includere una formula.

Può capitare inoltre che Excel non trovi il risultato esatto anche se in realtà esso esiste. Per evitare questo rischio, assicuratevi che l’opzione Approssimazione come visualizzata, nella scheda Strumenti, Opzioni, Calcolo, sia disattivata (figura 3).

Da questo link potete scaricare il foglio di lavoro di Excel relativo all’esempio mostrato.  Abbiamo duplicato i dati del foglio1 nel foglio2 ma questa volta inserendo la formula RATA() in B2 al posto del valore fisso e invece il valore fisso 60 in D2 a dimostrazione del fatto che la rata iniziale è calcolata in modo corretto.

Calcolare il rendimento annuo effettivo netto di qualsiasi forma di investimento equivale a stabilire la misura della redditività o rendimento finanziario dell’investimento con riferimento ad un tasso di interesse annuale ipotetico e al netto delle tasse.

Perchè un tasso di riferimento annuo? Avrebbe potuto essere anche un tasso mensile o biennale, non ha alcuna importanza se non quella di agevolare la comparazione con forme alternative di investimento, per le quali solitamente si parla di performance, risultato o interesse annuale.

E’ importante utilizzare un tasso annuale anche per almeno altri 3 motivi: primo, i tassi di interesse bancari e internazionali sono tutti espressi come tasso annuale, come il T.U.S. (Tasso Ufficiale di Sconto), il LIBOR (Tasso interbancario inglese a breve termine) , l’ EURIBOR (Tasso interbancario europeo a breve termine), ecc. Si tratta del tasso al quale le banche primarie si prestano il denaro tra loro a breve termine. Il TUS è il tasso al quale la banca centrale presta alle banche primarie.

Secondo, è più facile comparare il rendimento effettivo netto del nostro investimento con il tasso cosiddetto “senza rischio” il quale altro non è che quello dei BOT a 12 mesi, e terzo, infine, i rendimenti azionari, quelli dei fondi comuni di investimento e dei piani pensionistici per citarne solo alcuni, esprimono tutti dei tassi di rendimento annuali.

Prendiamo ora Microsoft Excel (o OpenOffice Calc, l’equivalente open source) e occupiamoci ora di una utilissima funzione: TIR.X

Attenzione! Prima di continuare verificate che il componente aggiuntivo ‘Strumenti di analisi’, se utilizzate Excel, risulti installato sul vostro PC, altrimenti seguite le indicazioni mostrate in questa figura.

La funzione TIR.X calcola il Tasso di Rendimento Interno (in inglese IRR o Internal Rate of Return) di un qualsiasi piano di investimento. In pratica il TIR è quel tasso di interesse (determinato in modo iterativo, cioè per tentativi) che pone in esatta equivalenza finanziaria i flussi di cassa, ovvero tutte le entrate e le uscite, di un investimento o di un piano finanziario indipendentemente dalla loro data di manifestazione, quindi con periodo variabile. La funzione TIR.X è molto flessibile perchè funziona sia con tasso nominale fisso, sia con tasso nominale variabile.

La funzione TIR.X è quindi uno strumento molto prezioso proprio per la sua estrema duttilità ma ha 2 difetti che non ne pregiudicano però a mio avviso la sua utilità: il primo è che fornisce uno scarto o imprecisione abbastanza trascurabile rispetto allo sviluppo manuale o prova del nove, il secondo è che non funziona quando il totale dei flussi negativi (uscite) supera quello dei flussi positivi (entrate), quindi in pratica non fornisce mai un tasso negativo.

Il tasso nominale è il tasso dichiarato dall’emittente del prestito, nel caso di una obbligazione, e corrisponde al tasso preso a riferimento per il calcolo delle cedole o dei rimborsi periodici. Il tasso nominale può essere annuale, semestrale, mensile, ecc e nulla ha a che vedere con il rendimento effettivo annuo netto che è appunto il dato che ricerchiamo e del quale la funzione TIR.X di Excel fornisce una valida approssimazione.

Nel foglio di Excel occorre preliminarmente riservare almeno 2 colonne ai dati di input per la funzione TIR.X, nel nostro caso, vedi figura 2, si tratta delle colonne B e C.

Più precisamente nella colonna B vanno inserire le date di ciascun fusso di cassa, nella colonna C invece vanno inseriti i relativi flussi di cassa, tenedo presente questa importantissima regola (altrimenti la funzione segnala un errore o fornisce dati incongruenti): i flussi negativi, quindi le uscite, vanno inseriti con il segno meno (-) davanti, quelli positivi con il segno più (+) o senza segno.

I flussi di cassa senza segno sono sempre considerati positivi. Nella colonna A abbiamo inserito le descrizioni di ciascun flusso di cassa, il primo rappresenta l’investimento iniziale, cioè la somma che vi viene effettivamente addebitata sul conto corrente dalla banca all’acquisto del titolo o alla data di emissione dell’obbligazione.

Una cosa importantissima da comprendere è che, se nella stessa data (intesa come valuta) avete più addebiti o accrediti, per esempio un addebito per € 25.000,00 per acquisto titoli e un’altro addebito di € 125,00 per commissioni su acquisto titoli (nell’esempio è lo 0,50% sul valore del titolo), dovete sommarli se entrambi sono addebiti (o accrediti) e invece prendere la differenza se uno è un addebito e l’altro un accredito (o viceversa).

In altre parole un flusso di cassa non è altro che il saldo netto contabile di più operazioni aventi la stessa data o valuta.

In excel il flusso di cassa va inserito con il segno meno (-) se questo saldo netto contabile rappresenta un esborso complessivo, mentre andrà inserito con il segno più (+) se si tratta di un introito complessivo, come ad esempio è il caso del rimborso finale del capitale.

Nell’esempio notate che la commissione dello 0,50% che la banca si tiene quale corrispettivo per la compravendita del titolo è applicata 2 volte, all’inizio dell’operazione e alla fine. Siccome in entrambi i casi si tratta di un costo, cioè di un addebito per € 125,00, il flusso di cassa relativo all’investimento iniziale del 2/8/2004 è di (-) € 25.125, mentre quello relativo al rimborso finale in data 2/2/2009 è di (+) € 24.875, perchè la commissione in questo caso è stata detratta dal rimborso finale del capitale.

Dalla riga 8 alla riga 16 vengono inseriti i flussi di cassa intermedi, pari alla cedola periodica a tasso fisso nominale del 1,5% semestrale (3% annuo : 2 ) meno la ritenuta fiscale del 12,50%, che la banca trattiene sulla cedola e versa all’erario.

L’importo della cedola semestrale lorda è quindi € 25.000,00 x 1,5% = € 375,00, quello della cedola semestrale netta è € 375,00 meno la ritenuta fiscale 12,50% (€ 46,88) = € 328,12.

Siccome la cedola è di fatto un saldo contabile netto positivo, cioè un incasso, il flusso di cassa ha segno positivo.

La durata complessiva dell’operazione, in questo caso l’acquisto di una obbligazione bancaria in fase di emissione, tenuta fino a scadenza, è di 4 anni e 6 mesi, per un totale di 9 cedole.

Da notare che sulla destra del foglio è visibile un ulteriore conteggio, che ho chiamato “sviluppo manuale” o “prova del nove”. In pratica mentre a sinistra sono rappresentati i flussi effettivi di cassa come si presentano nell’estratto conto, nella parte destra ho ricostruito un piano di investimento standard, ad esempio un BOT semestrale o un normalissimo prestito a tasso costante per tutta la durata dell’investimento con evidenziazione del capitale e degli interessi composti maturati ad ogni singola scadenza periodica.

I tassi di interesse evidenziati in blu di cella D5 (risultato funzione TIR.X) e in H5 (stesso valore) si intendono riferiti all’anno.

Nella cella D5 è stata inserita la funzione TIR.X che ha come primo argomento (valori) l’intervallo celle C7:C17 , come secondo argomento (date_pagam) l’intervallo celle B7:B17 e come terzo (ipotesi) nessun valore.

Il tasso di rendimento interno dell’operazione o rendimento effettivo netto globale è pari al 2,41%.

Questo tasso tiene conto di tutte le spese, commissioni e tasse relative all’operazione. Vedete che se impiegassimo la stessa somma iniziale (€ 25.125,00) al tasso semestrale effettivo dell’1,2060% (2,4119% : 2) dal 2/8/2004 fino al 2/2/2009 otterremmo un capitale futuro in data 2/2/2009 di € 27.987,32.

Ora nella parte sinistra invece dobbiamo calcolare il valore futuro dell’intera operazione al 2/2/2009. Per fare questo occorre sommare al valore di € 24.875 di cella D17 (che non è altro che l’ultimo flusso di cassa alla data del 2/2/2009) il valore futuro della serie di cedole e qui occorre fare attenzione.

Poichè gli importi relativi alle cedole vengono incassati in date differenti non sarebbe corretto fare la semplice somma, occorre invece determinare la somma dei valori futuri alla data di rimborso (2/2/2009) di tutte le cedole. Fortunatamente c’è un’altra funzione finanziaria di Excel che fa al caso nostro perchè ci semplifica di molto il lavoro: è la funzione VAL.FUT di cella D24:

VAL.FUT (tasso_int ; periodi ;pagam ; val_attuale; tipo)

che nel nostro caso assume questi valori:

=VAL.FUT(1,206% ; 9 ; 328,12 ; ;0)*-1

– 1,206% (tasso_int) è il tasso semestrale effettivo ottenuto dividendo per 2 il TIR (2,4119%)

– 9 sono i periodi (semestrali);

– 328,12 è l’importo (pagam) della cedola periodica;

– val_attuale è omesso;

– tipo vale ‘0’ (zero) perchè ci serve il valore alla fine di ciascun periodo.

Il risultato, € 3.099,62 rappresenta il valore futuro delle 9 cedole riferito alla data di scadenza dell’intera operazione e cioè il 2/2/2009.

Sommando € 3.099,62 a € 24.875 ,00 si ottiene il valore futuro globale, pari a € 27.974, 62.

Lo “sviluppo manuale” ci dava invece un risultato di € 27.987,32, con una differenza in eccesso di € 12,70

Per finire viene calcolato il valore attuale dell’intero investimento riferito ad oggi, 12 novembre 2007 , riprendendo empiricamente dal riquadro di destra il montante alla scadenza dell’ultima cedola (2/8/2007) che è € 26.998,61, moltiplicando questo importo per il rendimento effettivo annuo netto, rapportandolo alla frazione di anno (anno di 360 giorni) e infine sommandolo.

La funzione FRAZIONE.ANNO di cella H27 non fa altro che calcolare quanti giorni ci sono tra il 2/8/2007 ed oggi, il 12/11/2007 e dividerli per 360.

Da questo link potete scaricare il foglio di Excel ‘Calcolo rendimento effettivo netto con Excel.xls‘ dentro il file zippato ‘RendimentoAnnuoEffettivoNetto.zip’ in area download.